//Probeersel met ondergaande zon en zo
#include "functions.inc"

global_settings { ambient_light rgb<.05, .05, .05> }

//Zon
light_source {
    <0,.1,9999>
    color rgb <.6,.5,.5>
    
}
//Maan ofzo
light_source {
    <0,200,-199>
    color rgb <.2,.2,.4>
    shadowless
}

camera {
    location <0,4,-30>
    look_at <0,0,0>
}

//Lucht
sky_sphere {
    pigment {
	planar
	color_map {
	    [0.0 color rgb <.4,0,.4>]
	    [0.8 color rgb <.6,0,0>]
	    [0.97 color rgb <1,1,0>]
	    [1.0 color rgb <1,1,.6>]
	}
	warp {
	    black_hole <0,0,3>,2
	    falloff 2
	    strength 1.5
	    inverse
	}
	scale .3
    }
    pigment {
	granite
	color_map {
	    [0.0 color rgbt <1,1,1,1>]
	    [0.3 color rgbt <1,1,1,1>]
	    [0.4 color rgbt <1,.7,.7,.7>]
	    [0.5 color rgbt <1,1,1,.4>]
	    [1.0 color rgb <1,1,1>]
	}
	scale <1,.5,1>
    }
    rotate <2,0,0>
}


//Landtong
isosurface {
    function {(x) + pow(y,2) + pow(z,2)+f_granite(x*2, 0, z*2)/5}
    threshold .2
    accuracy .01
    max_gradient 11
    texture{pigment { 
	granite 
    }}
    texture {pigment {
	crackle form <-1,1,0>
	color_map {
	    [0.0 color rgbt <1,1,1,1>]
	    [0.3 color rgbt <1,1,1,1>]
	    [0.7 color rgbt <0,1,.1,0>]
	}
	scale .1
    }}
    finish { reflection 0 phong 1}
    scale <30,5,5>
    rotate <0,-70,0>
    translate <-4,0,10>
}

//Vuurtoren
union {
    cylinder {
	<0,0,0>
	<0,10,0>
	1.5
	texture {pigment {
	    spiral1 1
	    color_map {
		[0.5 color rgb <1,1,1>]
		[0.51 color rgb <1,0,0>]
	    }
	    rotate <90,0,0>
	    scale 3
	}}
	texture {pigment {
    	    crackle form <-1,1,0>
    	    color_map {
		[0.0 color rgbt <1,1,1,1>]
		[1.0 color rgbt <.3,.5,0,0>]
	    }
	scale 1.5
	}}
	finish {
	    diffuse 1
	}
	
    }
    cylinder {
	<0,10,0>
	<0,10.4,0>
	2
	pigment { color rgb <.7,.7,.7> }
    }
    cylinder {
	<0,10,0>
	<0,13,0>
	1.0
	pigment { color rgbt <.8,1,.8,.8> }
	finish {
	    reflection .1
	    specular 1
	    diffuse .5
	}
    }
    union {
	light_source {
	    <.3,12,0>
	    color rgb <1,1,1.5>
	    shadowless
	    spotlight
	    fade_distance 1500
	    point_at <1000,0,0>
	    radius 30
	    falloff 36
	}
	cylinder {
	    <0,10,0>
	    <0,11.3,0>
	    .3
	    pigment {
		color rgb <.5,.3,0>
	    }
	}
	difference {
	    sphere {
		<0,12,0>
		.8
	    }
	    union {
		sphere {
		    <0,12,0>
		    .7
		}
		box {
		    <0,0,-10>
		    <10,20,10>
		}
	    }
	    pigment {
		color rgb <.5,.3,0>
	    }
	    finish {
		reflection .1
		phong 1
		metallic
	    }
	}
	rotate <0,-55,0>
    }
    union {
	cone {
	    <0,13,0>
	    1.3
	    <0,15,0>
	    0
	}
	cylinder {
	    <0,10,0>
	    <0,10.4,0>
	    2
	}
	pigment { color rgb <.9,1,.9> }
	normal { 
	    bumps .5
	}
	finish { 
	    reflection .2
	    phong 1
	    metallic 
	}
    }
    //Lampje beneden
    union {
	light_source {
	    <0,5,-1.7>
	    color rgb <1,1,.7>
	    fade_power 3
	    fade_distance 2
	    looks_like {
		sphere {
		    <0,0,0>
		    .3
		    pigment {
			color rgb <1,1,1>
		    }
		    finish {
			ambient <.7,.7,.5>*20
		    }
		}
	    }    
	}
    	union {
	    torus {
		.30
		.05
		rotate <0,0,90>
	    }
	    torus {
		.30
		.05	
		rotate <90,0,0>
	    }
	    torus {
		.30
		.05
	    }
	    translate <0,5,-1.7>
	    pigment {
		color rgb <.3,.3,.7>
	    }
	    finish {
		reflection .4
	    }
	}	

    }
    translate <-7,0,-2>
}


//Zee
plane {
    <0,1,0>
    0
    pigment {
	color rgb <.5,.5,.7>
    }
    normal {
	granite .5
	scale 5
    }
    finish {
	reflection {.05 .2}
	phong .8
	diffuse .3
    }
}


//Sim-pel bootje, voor achtergrond.
union {
    difference {
	box {
	    <-2,-1,-1>
	    <2,1,1>
	    rotate <90,0,0>
	}
	box {
	    <-3,0,-2>
	    <3,2,2>
	}
	cylinder {
	    <2,-1,-3>
	    <2,-1,3>
	    1
	}
    }
	box {
	    <-1.3,0,-1>
	    <.6,.5,1>
	}
    
    translate <0,.5,0>
    pigment { color rgb <.4,.4,.4> }
    scale 10
    translate <-70,0,500>
}


#declare vogel=union {
    cylinder {
	<-1,0,0>
	<1,0,0>
	.3
	rotate <0,0,30>
    }
    sphere {
	<0,0,0>
	1
	translate <0,0,1>
	scale <.6,.2,1.5>
    }
    sphere {
	<0,0,0>
	1
	translate <0,0,-1>
	scale <.6,.2,1.5>
	rotate <20,0,0>
    }
    pigment { color rgb <.4,.4,.4> }
    scale 2
}


//Array vogels
union {
    object{vogel rotate <0,20,0> translate <0,50,400>}
    object{vogel rotate <0,45,0> translate <10,40,450>}
    object{vogel rotate <0,70,20> translate <-10,60,380>}
    object{vogel rotate <20,30,0> translate <20,50,420>}
    object{vogel rotate <10,140,20> translate <34,60,380>}
    object{vogel rotate <20,80,10> translate <39,46,420>}
    translate <-170,0,-100>
}

#declare paaltje=object {
    cylinder {
	<0,0,0>
	<0,5,0>
	.2
	finish {
	    specular .1
	}    
    }
}

//Schutting bij camera
#declare p=10;
#while (p>-10)
object{
    paaltje
    translate <p/1.7,-3,-24+p/20> 
    pigment {
	granite
	color_map {
	    [0.0 color rgb <1,.7,0>]
	    [0.5 color rgb <.9,.4,0>]
	    [1.0 color rgb <.7,.6,0>]
	}
	translate <.1,.1,0>
	scale <2,4,2>
    }
    normal {
        granite .6
        scale <.3,3,.3>
    }
}
#declare p=p-.65;
#end

//Schutting om palmboom
union {
    #declare p=0;
    #while (p>-6.28)
    object{
	paaltje
	translate <sin(p)*10,-2,cos(p)*10> 
	pigment {
	    granite
	    color_map {
		[0.0 color rgb <1,.7,0>]
		[0.5 color rgb <.9,.4,0>]
		[1.0 color rgb <.7,.6,0>]
	    }
	    translate <.1,.1,0>
	    scale <2,4,2>
	}
	normal {
    	    granite .6
    	    scale <.3,3,.3>
	}
    }
    #declare p=p-.04;
    #end
    
    cylinder {
	<0,0,0>
	<0,2.6,0>
	10
	pigment {
	    granite
	    color_map {
		[0.0 color rgb <.7,.7,.7>]
		[0.0 color rgb <1,1,.0>]
		[0.0 color rgb <1,.6,.0>]
	    }
	}
	normal {
	    granite
	}	
    }
        translate <20,-1,-10>
}

//Zand vooraan
box {
    <-10,0,-24>
    <10,1.5,-50>
    pigment {
	granite
	color_map {
	    [0.0 color rgb <.7,.7,.7>]
	    [0.0 color rgb <1,1,.0>]
	    [0.0 color rgb <1,.6,.0>]
	}
    }
    normal {
	granite
    }	
}



//Stam palm
union {
    parametric {
	function{sin(u)*(.3-(v*.1))+pow(v/3,3)*13}
	function{v}
	function{cos(u)*(.3-(v*.1))}
	<0,-1><6.28,1>
	pigment{
	    gradient y
	    sine_wave
	    color_map {
		[0 color rgb <.7,.4,0>]
		[1 color rgb <.7,.1,0>]
	    }
	    rotate <0,0,-3>	    
	    scale .05
	}
	finish {
	    diffuse .3
	    specular .2
	}
	normal {
	    granite
	    scale 2
	}
	scale <1,4,1>
	rotate <0,0,20>
    }
    translate <11,4,-10>
}

#declare palmblad=union{
    torus{
        4
        1
        translate <0,.1,0>
    }
    torus{
        4
        1
        translate <0,-.1,0>
    }
    rotate <90,0,0>
    translate <0,-5,0>
    clipped_by {union {
	cylinder {
	    <-10,0,0>
	    <10,-.1,0>
	    .1
	    scale <1,10,1>
	}
	#declare p=-40;
	#while (p<40)
	cylinder {
	    <p,0,-10>
	    <p,0,10>
	    .2
	    scale <.10,6,1>
	}
	#declare p=p+1;
	#end
    }}
    finish {
	reflection .1
	specular .2
	diffuse .5
    }
}

//Kruin palm
#declare s=seed(10);
union {
    #declare p=25;
    #while (p>0)
    object{
	palmblad 
	scale rand(s)+1
	translate <-1.6,0,0>
	rotate <0,0,rand(s)*100-50> 
	rotate <0,rand(s)*360,0>
	pigment {
	    granite
	    color_map {
		[0.0 color rgb <1,1,0>]
		[1.0 color rgb <0,1,0>]
	    }
	    scale 1
	}
    } 
    #declare p=p-1;
    #end
    translate <10,8,-10>
}